Office2PDM addin for MS Office

Users have long enjoyed the ability to check their SolidWorks files into and out of the Enterprise PDM vault from directly inside of SolidWorks. This is because Enterprise PDM has something called the CAD Editor that is a SolidWorks Addin that runs directly inside of SolidWorks.

Extensible CAD Technologies has developed an office editor to enable users to work with their MS Word, Excel and Powerpoint files in exactly the same way. Currently, users must close their MS Office files and then operate on them in Windows explorer.

Although we haven’t released the application for sale just yet, we are very close. In the meantime, we are offering a free beta version on our website to anyone who is willing to try it out and give us feedback. You can download the beta version from here: Office2PDM Beta

Note: We still have a little work to do including the help file. Also, after you save a new document you must hit the Refresh button. This is a temporary workaround and will be resolved shortly.

Send all feedback to support@extensiblecad.com

© Jeff Cope for Extensible By Design, 2009. | Permalink | 2 comments | Add to del.icio.us digg
Who's linking ? Technorati BlogPulse Google
Want more on these topics ? Browse the archive of posts filed under .NET, MS Office, SolidWorks Enterprise PDM.

Copyright 2007 Extensible By Design. All rights reserved.

I will also be presenting personally on Enterprise PDM Customization on Monday at 1:30pm.  Unfortunately they scheduled me at the same time as Joy Garon’s What’s New In EPDM 2009 but that is just how it goes.  Stop by my session if you can and if not, then stop by our booth and say hello.

© Jeff Cope for Extensible By Design, 2009. | Permalink | One comment | Add to del.icio.us digg
Who's linking ? Technorati BlogPulse Google
Want more on these topics ? Browse the archive of posts filed under MS Office, SolidWorks, SolidWorks Enterprise PDM.

Copyright 2007 Extensible By Design. All rights reserved.

What is the difference? In a nutshell, calling CreateObject( ) on an MS Office application interface will always create a new instance of the application and then return a handle to that instance. Calling CreateObject( ) on the SldWorks.Application interface will only create a new instance of SolidWorks if one isn’t already running. This basically ensures that only one instance of SolidWorks at a time is ever automated by your Macro. This is a basic coding pattern called “the Singleton” and it prevents untold suffering and countless tears. SolidWorks is so kind to us and many of us didn’t even know it.

Below are two Macros to illustrate the difference between SolidWorks and MS Office applications with regard to CreateObject( ). The first is an Excel Macro that automates SolidWorks and the second is a SolidWorks Macro that automates Excel. If you copy/paste the code, be sure you add references in each Macro project to the object library of the application you are automating. If you don’t know what the heck I am talking about, then just download the complete files from here.

• Excel Macro to automate SolidWorks:

‘Copyright 2007 by Extensible CAD Technologies, LLC – All rights reserved
‘Written 10/10/2007 by Jeff Cope
‘User assumes all risk for using the code below.

Sub AutomateSolidWorks()

‘Declare three handles to SolidWorks instances.
Dim swx1 As SldWorks.SldWorks
Dim swx2 As SldWorks.SldWorks
Dim swx3 As SldWorks.SldWorks

‘Use CreateObject( ) for the first instance. A new instance of SolidWorks IS NOT created.
‘Note: As we showed previously, using GetObject( ) without a filepath argument here would
‘return an error since no instances of SolidWorks are available to attach to yet.
Set swx1 = CreateObject(“SldWorks.Application”)
‘Use CreateObject( ) for the first instance. A new instance of SolidWorks IS NOT created.
Set swx2 = CreateObject(“SldWorks.Application”)
‘Use GetObject( ) for the first instance. A new instance of SolidWorks IS NOT created.
Set swx3 = GetObject(, ”SldWorks.Application”)
‘At this point, we should only have one SolidWorks window open and one SolidWorks process running.
‘Add new parts using each of the three handles

swx1.NewPart
swx2.NewPart
swx3.NewPart
‘We should now have one SolidWorks window open with three new SolidWorks parts loaded.

End Sub

• SolidWorks Macro to automate Excel:

‘Copyright 2007 by Extensible CAD Technologies, LLC – All rights reserved
‘Written 10/10/2007 by Jeff Cope
‘User assumes all risk for using the code below.

‘Declare three instances of the Excel.Application interface
Dim xl1 As Excel.Application
Dim xl2 As Excel.Application
Dim xl3 As Excel.Application

Sub main()

‘Use CreateObject( ) for the first instance. A new instance of Excel is created.
Set xl1 = CreateObject(“Excel.Application”)
‘A new Workbook gets added to this instance
xl1.Workbooks.Add
‘Make the instance visible so we can see what is happening
xl1.Visible = True

‘Use CreateObject( )for the first instance. A new instance of Excel is created.
Set xl2 = CreateObject(“Excel.Application”)
‘A new Workbook gets added to this instance
xl2.Workbooks.Add
‘Make the instance visible so we can see what is happening
xl2.Visible = True
‘At this point, we should be able to see two Excel windows running and each should have a
‘new Workbook added.

‘Use GetObject( ) for the first instance. A new instance of Excel IS NOT created. A handle
‘is simply returned to one of the existing instances (usually xl1).
Set xl3 = GetObject(, “Excel.Application”)
‘A new Workbook gets added to this instance
xl3.Workbooks.Add
‘Make the instance visible so we can see what is happening
xl3.Visible = True
‘At this point in the Macro’s execution, we should see two Excel windows (and two Excel processes)
‘running. However, we have three handles to Excel instances so two of the handles are pointing
‘to the same Excel instance.

‘Release handles to COM objects
Set xl1 = Nothing
Set xl2 = Nothing
Set xl3 = Nothing

‘One of the Excel windows will have two Workbooks in it instead of one. Note: If you
‘want to know which one, then just leave one of the instances invisible.
End Sub

© Jeff Cope for Extensible By Design, 2007. | Permalink | One comment | Add to del.icio.us digg
Who's linking ? Technorati BlogPulse Google
Want more on these topics ? Browse the archive of posts filed under CAD, MS Office, Macros, SolidWorks, SolidWorks API.

Copyright 2007 Extensible By Design. All rights reserved.

So what else is there? The GetObject( ) call has another trick up its sleeve that I didn’t discuss last time. Taking a look at its Intellisense signature provides a clue as to what this is.

In the method signature you actually see two parameters, PathName and Class. We know the Class is “SldWorks.SldWorks” but what is this PathName and to where does this path lead? Well, it turns out that this is the path to a SolidWorks file and that GetObject is so cool that not only can it return a reference to a SolidWorks application interface (e.g. SldWorks.SldWorks), it can also return a reference to a SolidWorks file as well.

Below are some examples on how you can use GetObject( ).

• Example 1 – The first example is basically review from the last post.  This code will usually get you a handle to an already running session of SolidWorks (i.e. a handle to an instance of the SldWorks.SldWorks class)

Dim swapp As SldWorks.ModelDoc2
Set swapp = GetObject(, “SldWorks.Application”)

• Example 2 – Iff (if and only if) you have “SLDPRT” associated with SolidWorks on your machine, then the code below will usually get you a handle to a SolidWorks document (i.e. a handle to an instance of the ModelDoc2 class) that resides at the address of “C:\myFiles\myPart.SLDPRT.” Note: In this particular case, an instance of SolidWorks will be created even if one doesn’t already exist. This was glossed over last time.

Dim swDoc As SldWorks.SldWorks
Set swDoc = GetObject(“C:\MyFiles\myPart.SLDPRT”)

• Example 3 – The code below will usually get you a handle to a SolidWorks document (i.e. a handle to an instance of the ModelDoc2 class) that resides at the address of “C:\myFiles\myPart.SLDPRT.” This is irregardless of whether or not you have “SLDPRT” associated with SolidWorks on your machine. Again, in this particular case, an instance of SolidWorks will be created even if one doesn’t already exist.

Dim swDoc As SldWorks.SldWorks
Set swDoc = GetObject(“C:\MyFiles\myPart.SLDPRT”, _ “SldWorks.Application”)

In a nutshell, GetObject can also be used to return a handle to a specific file.  To do this you simply include the path to the file as the first argument.  If you do this, then the second argument becomes optional unless you don’t have the particular file’s extension associated to the application in which you desire to open it.

“Ok Jeff. That’s pretty cool but what about that dirty little secret you promised us?”

We’ll have to save that for Part III and the final installment. I’ll give you a little hint, though. SolidWorks and Microsoft don’t make ALL of the same mistakes. Some but not ALL.

© Jeff Cope for Extensible By Design, 2007. | Permalink | No comment | Add to del.icio.us digg
Who's linking ? Technorati BlogPulse Google
Want more on these topics ? Browse the archive of posts filed under CAD, MS Office, Macros, SolidWorks, SolidWorks API.

Copyright 2007 Extensible By Design. All rights reserved.

Set swApp = CreateObject(“SldWorks.Application”)

Almost all SolidWorks Macros start out with that same, famous line of code. In fact, whenever you record a Macro in SolidWorks, the SolidWorks Macro Recorder is kind enough to fill that line in for you. What does it really mean, though? And why do a few Macros begin instead with this line of code:

Set swApp = GetObject(,”SldWorks.Application”)

Is there a difference? If there were no difference, then this would be a very short article. You have probably guessed correctly that there is a difference. The GetObject( ) call will attach to an existing instance of SolidWorks if one is running. If there is no instance of SolidWorks already running, then GetObject( ) will return an error. The CreateObject( ) call will also attach to an existing instance of SolidWorks if one is running. However, if there is no instance of SolidWorks already running, then CreateObject( ) will create one and attach to it. Because of this, most Macros contain the CreateObject( ) call as a way of hedging bets.

Why should I care? This behavior can be used to your advantage when you run into situations where you need to know if the application being called was running before you called it. You might need to know, for instance, whether or not to shut down Excel when your Macro is finished.Let’s say, for example, that a user who already has Excel up and running decides to run your Macro. If your Macro arbitrarily closes Excel when it is finished, then any unsaved changes to Workbooks will be lost. This could make you the target of nasty phone calls and maybe even litigation. One solution is to leave Excel running. This is not a desirable solution because of the resources that would be tied up by Excel (or any other application that you start up and leave running when finished). It is also a slight breach of programming etiquette.

How do I use this to my advantage? It is very simple.You start out by declaring an ‘alreadyRunning’ flag (i.e. a Boolean variable) and then you make a call to GetObject ( ). If that call doesn’t throw an error, then you make sure that ‘alreadyRunning’ is set to True and you procede with your Macro. If, however, the GetObject( ) call throws an error, then you make sure ‘alreadyRunning’ is set to False and you make a subsequent call to CreateObject( ). From there, you proceed with your Macro and at the end of your Macro, you put a line of code in that will close Excel because alreadyRunning=False.

Below is sample code for an Excel Macro (i.e. written for and residing in Excel) that employs this method. In this example, however, it is SolidWorks itself that needs to be either closed or left running depending on its state at Macro execution time. Because of this, the ‘alreadyRunning’ variable mentioned above is called “swxAlreadyOpen” for this specific application of the concept.You can download the files for this example from here.The Macro below will:

1. Run upon opening the Excel Workbook that contains it
2. Open the specified (i.e. hard-coded) model in SolidWorks
3. Query the model for some information
4. Write that information to the Excel Spreadsheet
5. Close the model
6. Close SolidWorks if it wasn’t running when the Workbook was opened

Disclaimer: The provider of this Macro assumes no liability for this Macro and makes no warranties for the Macro. Use at your own risk.

Note: This Macro builds upon an earlier and simpler example which can be downloaded from here.

Excuses: The Macro could benefit from some other programming best practices but I intentionally kept it as simple as possible so as to not confuse the readers.

**************Begin Excel Macro*********************

Option Explicit

Private Sub Workbook_Open()
‘This event handler is called every time the workbook is opened in Excel.

Dim swapp As SldWorks.SldWorks
‘Booleans have a default value of false.
Dim swxAlreadyOpen As Boolean
‘If the call below errors out, then we know SolidWorks wasn’t running. Workbook_OpenErrorHandler will handle this case for us.
On Error GoTo Workbook_OpenErrorHandler
‘Try to get a handle to an already running session of SolidWorks.
Set swapp = GetObject(, “SldWorks.Application”)
‘SolidWorks was already running. We know this because we would not have hit this line if SW was not running – the ErrorHandler would have already redirected us.

swxAlreadyOpen = True
‘Make sure we have a handle to SolidWorks.
If Not swapp Is Nothing Then
Call
populateSpreadsheet(swapp, Not swxAlreadyOpen)
Else
‘Put a msgbox here to warn the user that the macro couldn’t attach to SolidWorks.
Exit Sub
End If
Exit Sub
Workbook_OpenErrorHandler:
‘GetObject() call errored out so we know that SolidWorks isn’t running yet.
‘Create a new instance of SolidWorks.
Set swapp = CreateObject(“SldWorks.Application”)
If Not swapp Is Nothing Then
Call populateSpreadsheet(swapp, Not swxAlreadyOpen)
End If

‘Release COM objects
Set swApp = Nothing

End Sub

Sub populateSpreadsheet(ByRef swapp As SldWorks.SldWorks, ByVal
closeSolidWorksWhenFinished As Boolean)

Dim swDoc As SldWorks.ModelDoc2
Dim swPart As SldWorks.PartDoc
Dim swModelExt As SldWorks.ModelDocExtension
Dim xSheet As Excel.Worksheet
Dim xBook As Excel.Workbook
Dim strPartPath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim nStatus As Long
Dim sheetIndex As Integer
Dim vMassProps As Variant
‘Note: The file “Upper Fence – RH.SLDPRT” must reside in the same folder as this spreadsheet.
strPartPath = Excel.ActiveWorkbook.Path
strPartPath = strPartPath & “\Upper Fence – RH.SLDPRT”

Set swDoc = swapp.OpenDoc6(strPartPath, swDocPART, swOpenDocOptions_Silent Or SwConst.swOpenDocOptions_ReadOnly, “”, nErrors,
nWarnings)
Set swPart = swDoc
‘Since PartDoc inherits from ModelDoc2, we can query PartDoc for ModelDoc2.Extension
Set swModelExt = swPart.Extension
‘Get mass properties from modeldocextension object
vMassProps = swModelExt.GetMassProperties(1, nStatus)

‘Loop through worksheets
For Each xSheet In Excel.ActiveWorkbook.Sheets
If xSheet.Name = “PartProps” Then
‘Since PartDoc inherits from ModelDoc2, we can query PartDoc for ModelDoc2.GetTitle
xSheet.Cells(1, 2).Value = swPart.GetTitle
‘Since PartDoc inherits from ModelDoc2, we can query PartDoc for ModelDoc2.GetPathName
xSheet.Cells(2, 2).Value = swPart.GetPathName

If Not IsEmpty(vMassProps) Then
‘Mass
xSheet.Cells(3, 2).Value = vMassProps(5)
‘Area
xSheet.Cells(4, 2).Value = vMassProps(4)
‘Volume
xSheet.Cells(5, 2).Value = vMassProps(3)
Else ‘vMassProps is empty so just overwrite old
values with question marks
‘Mass
xSheet.Cells(3, 2).Value = “?”
‘Area
xSheet.Cells(4, 2).Value = “?”
‘Volume
xSheet.Cells(5, 2).Value = “?”
End If
End If
Next
‘Close SolidWorks if it wasn’t already running. Otherwise, just close the document being queried.
If closeSolidWorksWhenFinished Then
swapp.CloseAllDocuments (True)
swapp.ExitApp
Else
swapp.QuitDoc (swDoc.GetTitle)
End If

‘Release COM objects
Set swPart = Nothing
Set swModelExt = Nothing
Set swDoc = Nothing
End Sub

**************End Excel Macro*********************

Thanks to Wayne Tiffany who contributed to this article.

© Jeff Cope for Extensible By Design, 2007. | Permalink | 3 comments | Add to del.icio.us digg
Who's linking ? Technorati BlogPulse Google
Want more on these topics ? Browse the archive of posts filed under CAD, MS Office, Macros, SolidWorks, SolidWorks API.

Copyright 2007 Extensible By Design. All rights reserved.